しらんがな(´･ω･`)

  

ここまで出来た


モデルはキオ式ミク

キオ式アニキャラ3D act.3
http://kiomodel3.sblo.jp/



まだWeightの調節が所々出来てなくて
関節近くの挙動がおかしい  

キオ式ミクのインポートに挑戦してみる
  

最近どうもセカンドライフでの制作意欲が出ないので
過去に俺が作ったスクリプトを晒してみる

プリムの上へ複数人同時にお絵かきが出来るスクリプト

とても汚いです
方向ベクトル⇒オイラー角の計算とかかなり強引

// ******** プリムとスクリプトの構成 ********
・板（プリム）
　├ メインスクリプト
　├ 子スクリプト
　└ 線（プリム）
　　　└ 線のスクリプト
・線消し
　└ 線消しスクリプト


// ******** 板：メインスクリプト ********
integer giLinkNum;
integer giLinkNumMax = 20;

list glName;
list glVector;

integer MAX_PRIM = 5000;
integer ERASE_CHANNEL = 2131000;
integer gRezCount;

// ** 2点間にプリムを使って線を引く
// vector _vFrom Move  
// vector _vTo To
rezline( vector _vFrom,vector _vTo)
{
    vector vLineLength = _vTo - _vFrom;
    vector vRezPos = _vFrom +(vLineLength/2);
    
    // ** From - To から回転値を求める
    vector vRezRotation = <llAtan2(vLineLength.z,vLineLength.y) ,0 ,0 >;
    vRezRotation.z = llAtan2(
                        llSqrt(llPow(vLineLength.z,2)+llPow(vLineLength.y,2)),
                        vLineLength.x
                    );
    if(vRezRotation.x < 0)  vRezRotation.x += 2*PI;
    
    if(MAX_PRIM > gRezCount) // 現在のRezしたプリムのカウントが許容範囲を下回っていた場合
    {
        // ** 線を引く子スクリプトにメッセージを送る
        //  1: 送り先
        //  2: 引く線の長さ＋メッセージリンク受信判断
        //  3: 線をRezする位置
        //  4: 回転
        llMessageLinked(
            LINK_THIS,      // 1:
            llFloor(llVecMag(vLineLength)*100+1)*giLinkNumMax + (giLinkNum = ++giLinkNum % giLinkNumMax), // 2:
            (string)vRezPos, // 3:
            (key)((string)llEuler2Rot(vRezRotation)) // 4:
        );
    }
    
    // ** Rezしたプリムのカウントを増やす
    ++gRezCount;
}

// ** プリムのカウントを更新
reloadPrimCount()
{
    llSetText("現在のプリム: "+(string)gRezCount+"/"+(string)MAX_PRIM,<1,1,1>,1);
}

// ** エラーメッセージ
error(key _kTarget)
{
    llInstantMessage(_kTarget, "RC 1.21.0以上のセカンドライフクライアントで使用してください。");
}

default
{
    state_entry()
    {
        reloadPrimCount();
        llListen(ERASE_CHANNEL, "", NULL_KEY, "");
    }
    
    on_rez(integer n){llResetScript();}
    listen(integer _channel, string _name, key _key, string _message){llSleep(10.0);reloadPrimCount();}
    
    touch_start(integer _iDispatchAgentCount)
    {
        reloadPrimCount();
        
        integer i;
        for(i = 0 ; i < _iDispatchAgentCount ; i++)
        {
            if(llDetectedTouchPos(i) != ZERO_VECTOR)
            {
                if(llListFindList(glName, [llDetectedKey(i)]) == -1)
                {
                    if(MAX_PRIM > gRezCount)
                    {
                        glName += llDetectedKey(i);
                        glVector += llDetectedTouchPos(i);
                    }
                    else
                    {
                        llWhisper(0, "プリム数が限界なので一回消してね！");
                    }
                }
            }
            else    // クライアントがllDetectedTouchPos関数をサポートしていない
            {
                error(llDetectedKey(i));
            }
        }
    }
    touch(integer _iDispatchAgentCount)
    {
        integer i;
        for(i = 0 ; i < _iDispatchAgentCount ; i++) // 複数のキャラクターが同時にタッチした場合の処理
        {
            integer iFoundIndex = llListFindList(glName,[llDetectedKey(i)]);
            vector vTouchPos = llDetectedTouchPos(i);
            if(iFoundIndex >= 0)
            {
                rezline(llList2Vector(glVector, iFoundIndex),vTouchPos);
                glVector = llListReplaceList(glVector, [vTouchPos], iFoundIndex, iFoundIndex);
            }
            else if( vTouchPos == ZERO_VECTOR)    // クライアントがllDetectedTouchPos関数をサポートしていない
            {
                error(llDetectedKey(i));
            }
            else
            {
                if(MAX_PRIM > gRezCount){
                    glName += llDetectedKey(i);
                    glVector += vTouchPos;
                }
            }
        }
    }
    touch_end(integer _iDispatchAgentCount)
    {
        reloadPrimCount();
        
        integer i;
        for(i = 0 ; i < _iDispatchAgentCount ; i++)
        {
            integer iFoundIndex = llListFindList(glName,[llDetectedKey(i)]);
            if(iFoundIndex >= 0)
            {
                rezline(llList2Vector(glVector,iFoundIndex),llDetectedTouchPos(i));
                glName = llDeleteSubList(glName, iFoundIndex,iFoundIndex);
                glVector = llDeleteSubList(glVector, iFoundIndex,iFoundIndex);
            }
        }
    }
}

// ******** 板：子スクリプト ********
// ** SIMの処理能力と相談しながらスクリプト自体を増やして
// ** 増やした数だけPIPE_COUNTを書き換えてね。
string PRIM_NAME = "※線になるプリム";
integer PIPE_COUNT = 10;

default
{
    link_message(integer _iSender, integer _iNum, string _sStr, key _iId)
    {
        if(_iNum % PIPE_COUNT == 0)
        llRezObject("RezBox2", (vector)_sStr, ZERO_VECTOR, (rotation)((string)_iId), _iNum/20);
    }
}


// ******** 線：線のスクリプト ********
default
{
    on_rez(integer n)
    {
        llSetScale(<(float)n/100,0.01,0.01>);
        integer zn = (integer)llFrand(200);
        llListen(2131000 + n,"",NULL_KEY,"");
    }
    listen(integer a,string b,key c,string d)
    {
        llDie();
    }
}



// ******** 線消し：線消しスクリプト ********
default
{
    state_entry()
    {
        llSetText("消し",<1,1,1>,1);
    }

    touch_start(integer total_number)
    {
        llWhisper(0,llDetectedName(0)+"が全消ししたよ");
        integer i;
        for(i = 0 ; i < 200 ; ){
            if(llGetRegionTimeDilation() < 1){
                //llOwnerSay((string)llGetRegionTimeDilation());
            }else{
                llSleep(0.003);
                llWhisper(2131000 + i, "Touched.");
                i++;
            }
        }
    }
}